Start-Up VBS

Questo script (vbs) serve a monitorare i programmi e i servizi che si avviano automaticamente quando accendiamo il pc, in sostanza sostituisce in parte il comando msconfig direttamente da esegui per poi passare alla form di avvio.
Meglio passare alla pratica.... ;)
Come negli interventi precedenti riguardanti gli script se siete interessati potete copiare il seguente codice in grassetto per poi incollarlo nel blocco note e salvarlo con nome Start-Up.vbs
Al termine dell'operazione aprendo il file appena creato, si aprirà il blocco note con la lista dei programmi che partono all'avvio del sistema. Il file potrà essere chiuso senza salvarlo.

' The FileExt variable can be used to change the default output format
' Suggestions: htm, doc, rtf.  If not specified, defaults to .txt
  FileExt = "" : If FileExt = "" Then FileExt = "txt"
' The OpenWith variable is optional, to open results in specific program
' If variable is empty, Windows will use default program for FileExt type
  OpenWith = "" : If OpenWith <> "" Then OpenWith = Trim(OpenWith) & " "
'
With CreateObject("WScript.Network")
  ComputerName = .ComputerName
  UserName = .UserName
End With
Set fso = CreateObject("Scripting.FileSystemObject")
Set ws = CreateObject("WScript.Shell")
TmpFile = ws.ExpandEnvironmentStrings("%TEMP%") & "\Startup." & Trim(FileExt)
With fso.CreateTextFile(TmpFile, True)
  .WriteLine WriteCode("Lista di programmi avvio per: " & ComputerName & _
                       ", Nome Account: " & UserName & ", " & Now())
  .WriteLine WriteCode("")
  For Each o in GetObject _
      ("winmgmts:\\" & ComputerName & "\root\cimv2").ExecQuery(_
      "Select Name, Command, User, Location from Win32_StartupCommand",,48)
    If LCase(o.Command) <> "desktop.ini" _
        AND LCase(o.User) <> ".default" _
        AND InStr(LCase(o.User), "nt authority") = 0 Then
      .WriteLine WriteCode("Nome: " & o.Name)
      .WriteLine WriteCode("Comando: " & o.Command)
      .WriteLine WriteCode("User: " & o.User)
      .WriteLine WriteCode("Startup Location: " & o.Location)
      .WriteLine WriteCode("")
    Else
      s = s & vbcrlf & WriteCode("Nome: " & o.Name)
      s = s & vbcrlf & WriteCode("Comando: " & o.Command)
      s = s & vbcrlf & WriteCode("User: " & o.User)
      s = s & vbcrlf & WriteCode("Startup Location: " & o.Location)
      s = s & WriteCode("") & vbcrlf
    End If
  Next

  If s <> "" Then
    .WriteLine WriteCode(String(25, "*"))
    .WriteLine WriteCode("Servizi non compromettenti:")
    .WriteLine s
    .WriteLine WriteCode("")
  End If
  .WriteLine WriteCode("NOTE: Questa lista si cancellerà alla chiusura del file")
  .WriteLine WriteCode("")
  .WriteLine WriteCode("(http://gdminformatica.blogspot.com)")
  .Close
End With
' Some programs do not work properly with bWaitOnReturn argument
On Error Resume Next
ws.Run OpenWith & TmpFile,,True
On Error GoTo 0
fso.GetFile(TmpFile).Delete
Set fso = Nothing
Set ws = Nothing
Function WriteCode(sIn)
  If LCase(FileExt) = "htm" OR LCase(FileExt) = "html" Then
    WriteCode = sIn & "
"
  Else
    WriteCode = sIn
  End If
End Function
Condividi su Google Plus

Info su Giovanni Di Mauro

Questa è una breve descrizione nel blocco dell'autore sull'autore. Lo modifichi inserendo il testo su "Informazioni biografiche" nel pannello di amministrazione dell'utente.
    Commenti da Blogger
    Commenti da Facebook

0 commenti :

Posta un commento